Source/WebCore/platform/graphics/cocoa/GPUComputeCommandEncoderMetal.mm

/*
 * Copyright (C) 2017 Yuichiro Kikura (y.kikura@gmail.com)
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY APPLE INC. ``AS IS'' AND ANY
 * EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL APPLE INC. OR
 * CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
 * EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
 * PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
 * OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 * OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */

#import "config.h"
#import "GPUComputeCommandEncoder.h"

#if ENABLE(WEBGPU)

#import "GPUBuffer.h"
#import "GPUCommandBuffer.h"
#import "GPUComputePipelineState.h"
#import "GPUSize.h"
#import "Logging.h"

#import <Metal/Metal.h>

namespace WebCore {
    
inline MTLSize MTLSizeMake(GPUSize size)
{
    return {size.width, size.height, size.depth};
}
    
GPUComputeCommandEncoder::GPUComputeCommandEncoder(GPUCommandBuffer* buffer)
{
    LOG(WebGPU, "GPUComputeCommandEncoder::GPUComputeCommandEncoder()");

    if (!buffer || !buffer->platformCommandBuffer())
        return;

    m_computeCommandEncoder = (MTLComputeCommandEncoder *)[buffer->platformCommandBuffer() computeCommandEncoder];
}
    
void GPUComputeCommandEncoder::setComputePipelineState(GPUComputePipelineState* computePipelineState)
{
    if (!m_computeCommandEncoder || !computePipelineState)
        return;
    
    [m_computeCommandEncoder setComputePipelineState:static_cast<id<MTLComputePipelineState>>(computePipelineState->platformComputePipelineState())];
}
    
void GPUComputeCommandEncoder::setBuffer(GPUBuffer* buffer, unsigned offset, unsigned index)
{
    if (!m_computeCommandEncoder || !buffer)
        return;
    
    [m_computeCommandEncoder setBuffer:static_cast<id<MTLBuffer>>(buffer->platformBuffer()) offset:offset atIndex:index];
}
    
void GPUComputeCommandEncoder::dispatch(GPUSize threadgroupsPerGrid, GPUSize threadsPerThreadgroup)
{
    if (!m_computeCommandEncoder)
        return;
    
    [m_computeCommandEncoder dispatchThreadgroups:MTLSizeMake(threadgroupsPerGrid) threadsPerThreadgroup:MTLSizeMake(threadsPerThreadgroup)];
}

void GPUComputeCommandEncoder::endEncoding()
{
    [m_computeCommandEncoder endEncoding];
}
    
MTLComputeCommandEncoder *GPUComputeCommandEncoder::platformComputeCommandEncoder()
{
    return m_computeCommandEncoder.get();
}
    
} // namespace WebCore

#endif