Tools/TestWebKitAPI/Tests/WebKit/AccessibilityIncreaseContrast.mm

/*
 * Copyright (C) 2021 Apple Inc. All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY APPLE INC. AND ITS CONTRIBUTORS ``AS IS''
 * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
 * THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
 * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL APPLE INC. OR ITS CONTRIBUTORS
 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
 * THE POSSIBILITY OF SUCH DAMAGE.
 */

#import "config.h"

#if ENABLE(CFPREFS_DIRECT_MODE)

#import "PlatformUtilities.h"
#import "TestWKWebView.h"
#import "WKWebViewConfigurationExtras.h"
#import <WebKit/PreferenceObserver.h>
#import <WebKit/WKProcessPoolPrivate.h>
#import <WebKit/_WKProcessPoolConfiguration.h>

#if PLATFORM(MAC)
#import <pal/spi/mac/HIServicesSPI.h>
#endif

#if PLATFORM(IOS_FAMILY)
#include <pal/spi/cocoa/AccessibilitySupportSPI.h>
#include <wtf/SoftLinking.h>

#define NOTIFICATION_CENTER CFNotificationCenterGetDarwinNotifyCenter()
#define INCREASE_CONTRAST_PREFERENCE CFSTR("DarkenSystemColors")
#define ACCESSIBILITY_DOMAIN CFSTR("com.apple.Accessibility")
#else
#define NOTIFICATION_CENTER CFNotificationCenterGetDistributedCenter()
#define INCREASE_CONTRAST_PREFERENCE kAXInterfaceIncreaseContrastKey
#define ACCESSIBILITY_DOMAIN CFSTR("com.apple.universalaccess")
#endif

static bool receivedPreferenceNotification = false;

@interface WKPreferenceObserverForTestingIncreaseContrast : WKPreferenceObserver
- (void)preferenceDidChange:(NSString *)domain key:(NSString *)key encodedValue:(NSString *)encodedValue;
@end

@implementation WKPreferenceObserverForTestingIncreaseContrast
- (void)preferenceDidChange:(NSString *)domain key:(NSString *)key encodedValue:(NSString *)encodedValue
{
    receivedPreferenceNotification = true;
    [super preferenceDidChange:domain key:key encodedValue:encodedValue];
}
@end

TEST(WebKit, AccessibilityIncreaseContrast)
{
    WKWebViewConfiguration *configuration = [WKWebViewConfiguration _test_configurationWithTestPlugInClassName:@"WebProcessPlugInWithInternals" configureJSCForTesting:YES];
    auto webView = adoptNS([[TestWKWebView alloc] initWithFrame:NSMakeRect(0, 0, 300, 300) configuration:configuration addToWindow:YES]);

    CFPreferencesSetAppValue(INCREASE_CONTRAST_PREFERENCE, kCFBooleanFalse, ACCESSIBILITY_DOMAIN);

    auto observer = adoptNS([[WKPreferenceObserverForTestingIncreaseContrast alloc] init]);

    [webView synchronouslyLoadTestPageNamed:@"simple"];

    auto contrastCheck = [&] {
        return [webView stringByEvaluatingJavaScript:@"window.internals.userPrefersContrast()"].boolValue;
    };

    ASSERT_FALSE(contrastCheck());

    CFPreferencesSetAppValue(INCREASE_CONTRAST_PREFERENCE, kCFBooleanTrue, ACCESSIBILITY_DOMAIN);

    TestWebKitAPI::Util::run(&receivedPreferenceNotification);

    [webView synchronouslyLoadTestPageNamed:@"simple"];

    ASSERT_TRUE(contrastCheck());

    CFPreferencesSetAppValue(INCREASE_CONTRAST_PREFERENCE, nullptr, ACCESSIBILITY_DOMAIN);
}

#endif